[Pogeta]

Hallo Leute

Ich hätte eine Frage und zwar kann mir jemand helfen ich möchte ein Excelprogramm für Berechnungen der Hauptnutzungszeiten mit Schnittdaten erstellen und kenn mich bei excel nicht wirklich aus vlt. hätte jemand Ideen Verbesserungen usw für mich. mfg

die beilagen habe ich bisher geschafft mit google ,(

Der Beitrag wurde von Pogeta bearbeitet: 20.02.2024, 14:41 Uhr

Angehängte Datei(en)

 Unbenannt.PNG ( 36.05KB ) Anzahl der Downloads: 58
 Unbenannt2.PNG ( 48.81KB ) Anzahl der Downloads: 27

 

[Hawky]

Also Längsdrehen sollte kein Problem darstellen.
Was a bisserl schwieriger ist, ist das Plandrehen bei konstanter Schnittgeschwindigkeit. Hier muss man (wenn von außen nach innen) die Bearbeitung in 2 Schritte teilen. Einmal von außen bis Drehzahl max und dann der Rest.

Habe so eine Tabelle mal erstellt und die funktioniert eigentlich gut. Ist sogar mit Erklärungen.

Das einzige was nicht funktioniert ist ins Minus zu drehen. Also zum Beispiel von Ø5 auf Ø1 mit 1,2mm Überlauf (ich habe den Überlauf versehentlich also Ø angenommen) Drehen also eigentlich Ø-0,2mm. Hier wird dann eine Warnung eingeblendet.

[Andreas1964]

hätte jemand Ideen Verbesserungen usw für mich. mfg

Soweit aus dem Screenshot erkennbar ist die Berechnung zu sehr vereinfacht.
Die allgemeinen Formeln sind so einfach das hier Excel "nicht wirklich" ein Problem sein sollte.

Das Problem das ganz oft vergessen wird ist die Drehzahlbegrenzung, sagen wir mal wird haben Ø200 und wollen einen Ansatz Ø70 mit der Länge 50 drehen. Bei Vc300 und einer Drehzahlbegrenzung von 1000 U/min teilt sich der Zerspanbereich in 2 Teile, einen oberen und einen unteren.

Der Haken ist die Frage: Bei welchem Ø wird die Drehzahlbegrenzung erreicht? Denn sobald eine Zustellung <= diesem Ø ist drehen wir nur noch mit einer konstanten Drehzahl, sprich S und nicht mehr Vc! Und in dem Fall muss die Berechnung etwas anders sein.
 a.PNG ( 21.68KB ) Anzahl der Downloads: 26


B12: =(B2-B3)/2
B13: =AUFRUNDEN(B12/B5;0)
B14: =B12/B13
B15: =B4+B9+B10

B17: =B7/PI()/B8*1000
B18: =(B2-B17)/2

B20: =ABRUNDEN(B18/B14;0)
B21: =B2-B20*B14*2
B22: =(B2+B21)/2
B23: =B7*1000/(PI()*B22)
B24: =B15*B20/(B23*B6)

B26: =B13-B20
B27: =B8
B28: =B15*B26/(B27*B6)

B29: =B24+B28

Das ist "straight forward" wie man so schön sagt und für diesen Fall schon mal richtig, oder? ;-)

Ändern wir jetzt mal den Ansatz-Ø zu 180 sehen wir das die Schnittanzahl oberer/unterer Bereich Blödsinn ist, die Ursache liegt im Zustellweg der Grenze begraben, die Formel berücksichtigt nicht das der Ø der Drehzahlgrenze unter dem Ansatz-Ø liegt. Daher korrigieren wird das mit:

B18: =(B2-MAX(B3;B17))/2

Ändern wir jetzt mal den Mat-Ø zu 90 und den Ansatz-Ø zu 70, dann sehen wir das der Zustellweg der Grenze negativ wird... draufdrehen kann keiner. ;-) Wenn also der Mat-Ø kleiner dem Grenz-Ø wird, dann müssen wir den Zustellweg auf 0 begrenzen => kein oberer Bereich, alles wird mit konstant S gedreht.

B18: =MAX((B2-MAX(B3;B17))/2;0)

Und das war's für das Längsdrehen, mehr Fälle gibt es nicht... Plandrehen funktioniert äquivalent.

Wenn man das dann soweit hat kann man die blauen Eingabefelder aufteilen, für mehrere Ansatz-Ø brauche ich ja nur Ø und Länge, alles andere bleibt idR gleich... oder auch nicht und kann ggf. Überschreiben werden.
 b.PNG ( 49.27KB ) Anzahl der Downloads: 18


Dann ändern sich die Formeln so das man halt die Standardwerte nimmt wenn man keine speziellen hat.

B20: =($B$2-B11)/2
B21: =AUFRUNDEN(B20/WENN(B13<>"";B13;$B$3);0)
B22: =B20/B21
B23: =B12+WENN(B17<>"";B17;B7)+B18
B25: =WENN(B15<>"";B15;$B$5)/PI()/WENN(B16<>"";B16;$B$6)*1000
B26: =MAX((WENN(B10<>"";B10;$B$2)-MAX(B11;B25))/2;0)
B28: =ABRUNDEN(B26/B22;0)
B29: =WENN(B10<>"";B10;$B$2)-B28*B22*2
B30: =(WENN(B10<>"";B10;$B$2)+B29)/2
B31: =WENN(B15<>"";B15;$B$5)*1000/(PI()*B30)
B32: =B23*B28/(B31*WENN(B14<>"";B14;$B$4))
B34: =B21-B28
B35: =WENN(B16<>"";B16;$B$6)
B36: =B23*B34/(B35*WENN(B14<>"";B14;$B$4))
B37: =B32+B36

Das kann man nun einfach nach rechts ziehen soweit man es braucht und die Summe der Einzelzeiten zusammenrechnen mit
C1: =SUMME(B37:F37)/1440
formatiert als [m]:ss

 L__ngsdrehen.xlsx ( 12.56KB ) Anzahl der Downloads: 16


Alles klar?

Andreas.

Der Beitrag wurde von Andreas1964 bearbeitet: 22.02.2024, 10:03 Uhr

[Pogeta]

Ohaa ok so detaililiert in der Berechnungmaterie bin ich überhaupt nicht hab mich eigentlich bis dato nie damit beschäftigt hab immer geschätzt bzw an der maschine simuliert.

also versteh ich das richtig wenn ich jetzt nur von Ø100 auf Ø50 mit länge 70 drehen will dann passt das so ? sry ich bin da nicht so wiff leider

Angehängte Datei(en)

 L__ngsdrehen.xlsx ( 12.66KB ) Anzahl der Downloads: 15

 

[Andreas1964]

also versteh ich das richtig wenn ich jetzt nur von Ø100 auf Ø50 mit länge 70 drehen will dann passt das so ?

Das passt.

Formelmodelle dieser Art sind für grobe Abschätzungen okay, mach Dir noch was für das Bohren dazu, evt. Plandrehen.
Beim Fräsen auf Drehmaschinen versagen idR Formelmodelle, es sei denn man kann sich auf eindeutige Geometrien beschränken, z.B. Passfedernut, 6kt, etc.

Theoretisch kann man das dann weiter mit VBA ausbauen und sich einen Geometrieprozessor schreiben einen Zyklus wie G71/G72 kann. Das ist jedoch bei weitem nicht einfach und der nächste Schritt ist dann einen Interpreter zu schreiben der ein NC-Programm lesen kann... da stehen ja letzten Endes die Durchmesser und Längen drin.

Praktisch macht es jedoch wenig Sinn sich daran zu probieren, es sei denn man hat Spaß an Herausforderungen. Es gibt div. NC-Editoren die auch simulieren können und am Ende eine Zeit ausspucken. Kostet halt Geld statt Zeit und Kopfweh. :-)

Andreas.

[Pogeta]

Im großen und ganzen soll das ja nur eine ganz schnelle berechechnungprogramm für die Verkäufer bzw die Leute die nicht im zerspannungsbereich sind ;) also nur von startdurchmesser und enddurchmesser plus Länge und Material und das war’s alle andere soll das Programm machen


Der Beitrag wurde von Pogeta bearbeitet: 23.02.2024, 18:51 Uhr

[Pogeta]

bsp

Angehängte Datei(en)

 L__ngsdrehen.xlsx ( 17.83KB ) Anzahl der Downloads: 8

 

[Andreas1964]

Im großen und ganzen soll das ja nur eine ganz schnelle berechechnungprogramm für die Verkäufer bzw die Leute die nicht im zerspannungsbereich sind also nur von startdurchmesser und enddurchmesser plus Länge und Material und das war’s alle andere soll das Programm machen

Naja, das ist doch mal eine Herausforderung.

Dann brauchst Du zuerst mal eine Materialtabelle und diese muss dann so organisiert sein das für verschiedene Suchbegriffe die passende Werkstoffgruppe bekommt. Z.B.:

Werkstoff-gruppe Werkstoff-Nr spez. Schnittkraft von bis DIN (DE)
4,1 1.7218 2070 650 1100 25 CrMo 4
4,1 1.7707 1710 900 1450 30 CrMoV 9
4,1 1.7220 2240 750 1200 34 CrMo 4
4,1 1.6582 1800 800 1400 34 CrNiMo 6
4,1 1.7225 2500 800 1300 42 CrMo 4
4,1 1.7227 2500 800 1300 42 CrMoS 4
4,1 1.7228 50 CrMo 4
4,1 1.8159 2220 850 1300 50 CrV 4

Je Werkstoffgruppe macht man sich für die verschiedenen Fertigungsverfahren eine weitere Tabelle die dann die entsprechenden Schnittdaten vorhält.

"Werkstoff-
gruppe" Vcmin Vc Vcmax Fmin F Fmax Apmin Ap Apmax Emulsion
1,0 220 290 320 0,2 0,3 0,5 2 3 4,5 trocken
1,1 220 290 320 0,2 0,3 0,5 2 3 4,5 trocken
2,0 220 290 320 0,2 0,3 0,5 2 3 4,5 trocken
2,1 180 240 280 0,2 0,3 0,5 2 3 4 trocken
3,0 220 290 320 0,2 0,3 0,5 2 3 4,5 trocken
3,1 220 290 320 0,2 0,3 0,5 2 3 4,5 trocken
3,2 180 240 280 0,2 0,3 0,5 2 3 4 trocken
4,0 180 240 280 0,2 0,3 0,5 2 3 4 trocken
4,1 130 140 260 0,1 0,2 0,3 1 Emuls.
5,0 220 290 320 0,2 0,3 0,5 2 3 4,5 trocken
6,0 180 200 280 0,2 0,28 0,5 2 3 4 trocken
6,1 110 160 220 0,1 0,2 0,45 2 3 4 Emuls.

Das ganze fließt dann in meinem Schnittdatenrechner für das Drehen in so ein Blatt:
 a.PNG ( 84.73KB ) Anzahl der Downloads: 13


Jetzt muss Du noch einen Weg finden zu erkennen das man beim Innendrehen erstmal Vorbohren muss, es sei denn man hat ein Rohr. Beim Aussendrehen kann man schon sehr grob vereinfacht immer die gleiche Zustellung und Vorschub nehmen (ø12 auf ø6 drehen mit ap3 und fz 0,35 ist auch Lötsinn), beim Innendrehen macht es jedoch einen deutlichen Unterschied weil die Bohrstange a) einen anderen Durchmesser hat und b) mal mehr mal weniger auskragt was andere Schnittdaten bedingt.

Wenn das auch automatisch funktionieren soll... dann musst Du Dir was überlegen anhand welcher Kriterien Du welchen Bohrer / welche Bohrstange in welcher Ausführung (HM/Stahl/...) in welchem Durchmesser wählen willst.

Nun ja, ich sag mal "nur die Durchmesser und Länge eingeben und dann kommt da eine Zeit raus..." ist eine nette Idee, selbst mit Kenntnissen in der Zerspanung nicht einfach zu lösen.

Ich hab auf der Arbeit Solidworks, ist ein CAD Programm falls Dir das nichts sagt. In dem gibt es auch ein Costing-Modul mit dem "können" Konstrukteure abschätzen wie hoch die Herstellkosten sind.... nette Idee, IMHO ohne praktischen Nutzen.
https://help.solidworks.com/2024/german/Sol...m?verRedirect=1

Ein Konstrukteur kann bei einer Veränderung am Bauteil erkennen ob es teurer oder günstiger geworden ist, ja, aber ein Verkaufspreis kommt da nicht wirklich raus.

Okay, ich denke nun hast Du einen kurzen Einblick bekommen was Du da eigentlich machen sollst.
Und mal nebenbei, ich sitze in der AV und Zeiten berechnen wie lange was wo dauert mache ich jeden Tag und das nicht erst seit gestern.

Wenn mein Chef mir diese Aufgabe stellen würde, dann würde ich mal anmerken das es schon vor 30 Jahren die Idee gab eine Zeichnung unter einen Scanner zu legen und dann kommt da ein fertiges Programm / Herstellkosten raus... ja klar.

Heutzutage gibt es wieder so eine fixe Idee das die KI alle diese Probleme löst... das die dummen Maschinen aber nur den Blödsinn nachplappern den sie irgendwo im Internet gelesen haben hat noch niemand wirklich geblickt.

Andreas.