TNC320 Kontur in Mehrfachschnitten ae programmieren?

Hallo zusammen,
ich bin neu hier und versuche gerade die Möglichkeiten der Programmierung an einer TNC320 auszuloten.
Weiß jemand in der Comunity, wie man auf einer TNC320 (771851-4 SP3) eine "freie Kontur" in Mehrfachschnitten ae programmieren kann?
Ich habe bisher nur Lösungsansätze mit Zustellung inkremental in Z gefunden und keine in XY.
Danke im Voraus für die Rückmeldungen.

Stephan

mit DR im Werkzeugaufruf

Wenn du den Zyklus 25 (Konturzug) bereits hast, dann geht dort nur die Zustellung in der Z-Achse...ansonsten mit dem Werkzeugaufmass DR (Aufmass im Radius) "händisch" programmieren

"händisch" oder mit Q-Parameter

Also das "händisch" auszuprogrammieren halte ich nur für Sinnvoll wenn es sehr wenig Zustellungen sind.

Ich mache das normalerweise mit Q-Parameter und einem Sprungbefehl und über das Aufmaß des Konturzyklus (25) oder DR des Werkzeuges.

Sieht dann etwa so aus:


Konturzyklus
QR63 = xx Start DR (=Aufmaß) festlegen
TOOL CALL DR+QR63
LBL 901
CYCLE CALL
QR63 = QR63 - xx Zustellung festelgen
TOOL CALL DR+QR63
FN 11: IF +QR63 GT +xx GOTO LBL 901 Wert festlegen an dem die Schleife beendet wird (sollte normalerweise der Zustellwert sein, wenn das falsch ist kann DR- rauskommen!)
CALL LBL 10
Entweder hier dann noch auf DR0 durchfahren oder gleich den Schlichtzyklus programmieren.


Selber testen, hierfür wird keine Haftung übernommen, hab ich jetzt nur schnell zusammengeschrieben.

Hallo,
wenn Zyklus 25 vorhanden dann gibt es Aufmass Seite. für mehrere seitliche Zustellungen kann man ein kleines Hilfsprogramm mit Q Parametern erstellen. etwa so:

0 BEGIN PGM ABSATZ MM
1 FN 10: IF +Q56 NE +0 GOTO LBL 30
2 Q56 = 100
3 LBL 30
4 CYCL DEF 25 KONTUR-ZUG ~
Q1=+0 ;FRAESTIEFE ~
Q3=+0 ;AUFMASS SEITE ~
Q5=+0 ;KOOR. OBERFLAECHE ~
Q7=+Q56 ;SICHERE HOEHE ~
Q10=+0 ;ZUSTELL-TIEFE ~
Q11= AUTO ;VORSCHUB TIEFENZ. ~
Q12= AUTO ;VORSCHUB RAEUMEN ~
Q15=+1 ;FRAESART
5 M3
6 ;
7 Q61 = Q55
8 ;
9 LBL 10
10 FN 9: IF +Q61 EQU +Q54 GOTO LBL 20
11 Q61 = Q61 - Q53
12 FN 11: IF +Q61 GT +Q54 GOTO LBL 12
13 Q61 = Q54
14 LBL 12
15 Q5 = Q61 + Q53
16 Q1 = - Q53
17 Q10 = - Q53
18 ;
19 Q60 = Q50
20 LBL 13
21 Q60 = Q60 - Q52
22 FN 11: IF +Q60 GT +Q51 GOTO LBL 11
23 Q60 = Q51
24 LBL 11
25 Q3 = Q60
26 M99
27 FN 9: IF +Q60 EQU +Q51 GOTO LBL 10
28 FN 9: IF +0 EQU +0 GOTO LBL 13
29 ;
30 LBL 20
31 LBL 0
32 END PGM ABSATZ MM

im Hauptprogramm definiert man die Hauptparameter etwa so:

0 BEGIN PGM ABSATZ-MUSTER MM
1 BLK FORM 0.1 Z X+0 Y+0 Z-31
2 BLK FORM 0.2 X+150 Y+100 Z+0
3 TOOL CALL 1 Z S1000 F1000
4 Q50 = 90 ;MAX. AUFMASS
5 Q51 = 0.2 ;MIN. AUFMASS
6 Q52 = 50 ;SEITLICHE ZUSTELLUNG
7 Q53 = 1 ;ZUSTELLUNG IN Z
8 Q54 = 0 ;ENDTIEFE
9 Q55 = 10 ;STARTTIEFE
10 Q56 = 100 ;SICHERE HOEHE
11 CYCL DEF 270 KONTURZUG-DATEN ~
Q390=+2 ;ANFAHRART ~
Q391=+1 ;RADIUS-KORREKTUR ~
Q392=+5 ;RADIUS ~
Q393=+90 ;MITTELPUNKTSWINKEL ~
Q394=+35 ;ABSTAND
12 CYCL DEF 14.0 KONTUR
13 CYCL DEF 14.1 KONTURLABEL50
14 CALL PGM TNC:ZYKLEN\ABSATZ
15 ;
16 ;
17 M30
18 ;
19 LBL 50
20 L X+0 Y+10
21 L X+150
22 LBL 0
23 END PGM ABSATZ-MUSTER MM

So mach ich das jedenfalls auf meiner mit 530er Steuerung. Bei Interesse kann ich das alles noch deutlicher erklären.
Gruß Jens

P.S. schon wieder an Admin. die Beitragsvorschau erscheint bei mir immer noch kaum lesbar vor dem dunklen Hintergrund. Tschuldigung für das Generve.

Vielen Dank homerq & jtm90,
ich werde es damit mal versuchen

Der Beitrag wurde von Meister2011 bearbeitet: Heute, 06:56 Uhr